package labs.otuome.air.myapp.view.panel
{
   import flash.display.NativeWindow;
   import flash.events.Event;
   import flash.events.NativeWindowDisplayStateEvent;
 
   public interface OwnableWindow
   {
      function get windowOwner():NativeWindow;
      function set windowOwner( value:NativeWindow ):void;
 
      function respondToOwnerWindowActivated( event:Event ):void;
      function respondToOwnerWindowMinimizedOrRestored( event:NativeWindowDisplayStateEvent ):void;
      function respondToOwnerWindowClosing( event:Event ):void;
   }
}

package labs.otuome.air.myapp.view.panel
{
   import flash.display.NativeWindow;
   import flash.display.NativeWindowDisplayState;
   import flash.events.Event;
   import flash.events.MouseEvent;
   import flash.events.NativeWindowDisplayStateEvent;
 
   import mx.events.FlexEvent;
 
   import spark.components.Button;
   import spark.components.RichText;
 
   /**
    * Spark Window component subclass.
    * @author Hasan Otuome
    */
   public class FloatingPanelView extends FloatingPanelUI implements OwnableWindow
   {
      ///////////////////////////////////////////////////////////////////////////
      // PRIVATE PROPERTIES
      ///////////////////////////////////////////////////////////////////////////
      private var _panelTitle:String;
      private var _windowOwner:NativeWindow;
      //////////////////////////////////////////////////////////////////////////
      // PUBLIC PROPERTIES
      /////////////////////////////////////////////////////////////////////////
      [SkinPart (required=false)]
      public var header:Button;
 
      [SkinPart (required=false)]
      public var toggle:Button;
 
      [SkinPart (required=false)]
      public var contentTitle:RichText;
 
      /**
      * Sets the panel's title. 
      * @param value
      */		
      public function set panelTitle( value:String ):void
      {
           _panelTitle = value;
      }
      /**
      * Allows you to specify an owner for this Spark 
      * Window instance. Used only until the Flex SDK 
      * adds support for owned native windows to Spark 
      * Windows.
      */		
      public function get windowOwner():NativeWindow
      {
           return _windowOwner;
      }
      public function set windowOwner( value:NativeWindow ):void
      {
           _windowOwner = value;
      }
      ///////////////////////////////////////////////////////////////////////////
      // PUBLIC METHODS
      ///////////////////////////////////////////////////////////////////////////
      /**
      * Constructor 
      */		
      public function FloatingPanelView()
      {
        super();
 
        addEventListener( FlexEvent.CREATION_COMPLETE, _onCreationComplete, false, 0, true );
      }
      //---------- OwnableWindow implementations --------------------
      /**
      * Adjust the display ordering of this 
      *	instance as it relates to its owner. 
      */
      public function respondToOwnerWindowActivated( event:Event ):void
      {
        this.nativeWindow.orderInFrontOf( _windowOwner );
      }
 
      /**
      * Show/hide this instance based 
      *	on the display state of its owner. 
      */
      public function respondToOwnerWindowMinimizedOrRestored( event:NativeWindowDisplayStateEvent ):void
      {
        switch (true)
        {
           case (event.beforeDisplayState == NativeWindowDisplayState.MINIMIZED):
             this.restore();
             break;
           case (event.afterDisplayState == NativeWindowDisplayState.MINIMIZED):
             this.minimize();
             break;
        }
      }
 
      /**
      * Close this instance when its owner is closed. This 
      *	will be handled automatically if the owner is 
      *	the main application window.  
      */
      public function respondToOwnerWindowClosing( event:Event ):void
      {
        this.close();
      }
      //////////////////////////////////////////////////////////////////////////
      // OVERRIDES
      /////////////////////////////////////////////////////////////////////////
 
      ////////////////////////////////////////////////////////////////////////
      // PRIVATE METHODS
      ///////////////////////////////////////////////////////////////////////
      /**
      * CREATION_COMPLETE event handler. 
      * Ensures this instance responds to 
      * display state changes of the 
      * instance's owner. 
      * @param e
      */		
      private function _onCreationComplete( e:FlexEvent ):void
      {
        if (_windowOwner)
        {
           _windowOwner.addEventListener( Event.ACTIVATE, respondToOwnerWindowActivated, false, 0, true );
           _windowOwner.addEventListener( NativeWindowDisplayStateEvent.DISPLAY_STATE_CHANGE, respondToOwnerWindowMinimizedOrRestored, false, 0, true );
           _windowOwner.addEventListener( Event.CLOSING, respondToOwnerWindowClosing, false, 0, true );
        }
 
        removeEventListener( FlexEvent.CREATION_COMPLETE, _onCreationComplete );
      }
   }
}

<?xml version="1.0" encoding="UTF-8"?> 
<project default="4. Package Application" name="[Your Flex Project Name]"> 
	<!-- Framework properties -->
	<property name="FLEX_HOME" value="[/path/to/your/flex/4.5/sdk]" /> 
	<property name="AIR_GLOBAL" value="${FLEX_HOME}/frameworks/libs/air/airglobal.swc" /> 
	<property name="ADL" value="${FLEX_HOME}/bin/adl" /> 
	<property name="ADT" value="${FLEX_HOME}/lib/adt.jar" /> 
	<property name="PFI" value="${FLEX_HOME}/lib/pfi.jar" /> 
	<property name="FLEX_TASKS" value="${FLEX_HOME}/ant/lib/flexTasks.jar" /> 
	<property name="LOCALE" value="en_US" /> 
 
	<!-- Project properties --> 
	<property name="project_root" value="[/path/to/your/flex/mobile/project]" /> 
	<property name="class_path" value="${project_root}/src" /> 
	<property name="lib_path" value="${project_root}/libs" />
	<property name="splash_path" value="${class_path}/Default.png" /> 
	<property name="app_name" value="[YourApp]" /> 
	<property name="app_root_dir" value="." /> 
	<property name="app_type" value="mxml" /> 
	<property name="assets_dir_name" value="[name_of_your_assets_dir]" />
	<property name="debug_mode" value="false" />
 
	<!-- Certificate properties --> 
	<property name="cert_loc" value="${app_root_dir}/[path/to/your/certs]" />
	<property name="ios_keystore" value="${cert_loc}/[your_cert_name].p12" /> 
	<property name="ios_pass" value="[your_cert_password]" />
	<property name="ios_provisioning" value="${cert_loc}/[your_provisioning_profile].mobileprovision" />
 
	<!-- Application properties -->
	<property name="swf_file" value="${app_name}.swf" /> 
	<property name="air_file" value="${app_name}.air" /> 
	<property name="ipa_file" value="${app_name}.ipa" /> 
	<property name="app_descriptor" value="${class_path}/${app_name}-app.xml" /> 
	<property name="main_class" value="${class_path}/${app_name}.${app_type}" />
	<property name="build_dir" location="${app_root_dir}/build" /> 
	<property name="debug_dir" location="${app_root_dir}/build/debug" /> 
	<property name="publish_dir" location="${app_root_dir}/build/deploy" /> 
	<property name="assets_dir" location="${class_path}/${assets_dir_name}" />
	<property name="output_loc" location="${publish_dir}/${swf_file}" />
 
	<!-- Use the Flex ANT tasks for easier compilation -->
	<taskdef name="mxmlc" classname="flex.ant.MxmlcTask" classpath="${FLEX_TASKS}"/>
 
	<!-- Clean existing directories --> 
	<target name="1. Cleanup Directories" description="clean up"> 
		<delete dir="${debug_dir}" /> 
		<delete dir="${publish_dir}" /> 
		<delete dir="${build_dir}" /> 
	</target> 
 
	<!-- Create required directories --> 
	<target name="2. Build New Directories" depends="1. Cleanup Directories"> 
		<mkdir dir="${build_dir}" /> 
		<mkdir dir="${debug_dir}" /> 
		<mkdir dir="${publish_dir}" /> 
	</target>
 
	<!-- Compile SWF to build-directory for packaging --> 
	<target name="3. Compile SWF" depends="2. Build New Directories"> 
		<mxmlc 
			file="${main_class}" 
			output="${output_loc}" 
			locale="${LOCALE}" 
			static-rsls="false" 
			accessible="false" 
			configname="airmobile" 
			debug="${debug_mode}" 
			failonerror="true" 
			fork="true" 
			maxmemory="512m">
			<source-path path-element="${class_path}"/>
			<compiler.library-path dir="${FLEX_HOME}/frameworks" append="true">
				<include name="libs/*" />
			</compiler.library-path>
			<library-path file="${FLEX_HOME}/frameworks/locale/${LOCALE}" append="true"/>
			<library-path dir="${lib_path}" includes="*.swc" append="true"/>
			<external-library-path file="${AIR_GLOBAL}" append="true"/>
		</mxmlc>
	</target>
 
	<!-- Package the application to an ipa file & save it in the publish directory --> 
	<target name="4. Package Application" depends="3. Compile SWF"> 
		<java jar="${ADT}" fork="true" failonerror="true"> 
			<arg value="-package"/>
			<arg value="-target"/>
			<arg value="ipa-test"/>
			<arg value="-provisioning-profile"/>
			<arg value="${ios_provisioning}"/>
 
      			<arg value="-storetype"/>
			<arg value="pkcs12"/>
			<arg value="-keystore"/>
			<arg value="${ios_keystore}"/>
			<arg value="-storepass"/>
			<arg value="${ios_pass}"/>
 
			<arg value="${ipa_file}"/>
			<arg value="${app_descriptor}"/>
			<arg value="${output_loc}"/>
 
			<arg value="-C" /> 
			<arg value="${class_path}"/>
			<arg value="${splash_path}"/>
 
			<arg value="-C" /> 
			<arg value="${class_path}"/>
			<arg value="${assets_dir}/icons/." /> 
		</java> 
	</target>
</project>

<content>[This value will be overwritten by Flash Builder in the output app.xml]</content>

<content>/path/to/your/application.swf</content>

<iPhone>
    <InfoAdditions><![CDATA[
<key>UIDeviceFamily</key>
<array>
<string>1</string>
<string>2</string>
</array>
]]></InfoAdditions>
    <requestedDisplayResolution>high</requestedDisplayResolution>
</iPhone>

package labs.otuome.air.myapp.model.vo.google
{
	/**
	 * Value object representing 
	 * application analytics data.
	 * @author Hasan Otuome
	 */
	public class AnalyticsData
	{
		///////////////////////////////////////////////////////////////////////
		// PRIVATE PROPERTIES
		//////////////////////////////////////////////////////////////////////
 
		/////////////////////////////////////////////////////////////////////
		// PUBLIC PROPERTIES
		/////////////////////////////////////////////////////////////////////
		//------------------- Track Types ---------------------------------//
		public static const URL:String 			= 'myapp_pageViewTrack';
		public static const EVENT:String 		= 'myapp_eventTrack';
		//------------------- Virtual URLs ---------------------------------//
		public static const INSTALL:String 		= '/app/installed';
		public static const TRIAL:String 		= '/app/trial';
		public static const PURCHASE:String 		= '/app/purchase';
		public static const REGISTRATION:String 	= '/app/registered';
		public static const HELP:String 		= '/view/help';
		public static const BUG:String 			= '/report/bug';
		/**
		 * The type of data this instance 
		 * represents, either AnalyticsData.VIEW 
		 * or AnalyticsData.EVENT. 
		 */		
		public var type:String;
		/**
		 * The data value to associate with this track. 
		 */		
		public var value:Object;
		//------------------- Event-only ---------------------------------//
		/**
		 * For event tracks, a custom event category. 
		 */		
		public var category:String;
		/**
		 * For event tracks, the action related to the event. 
		 */		
		public var action:String;
		/**
		 * For event tracks, a custom label to 
		 * associate with the event. 
		 */		
		public var label:String;
		/////////////////////////////////////////////////////////////////////
		// PUBLIC METHODS
		/////////////////////////////////////////////////////////////////////
		/**
		 * Constructor 
		 */		
		public function AnalyticsData(){}
 
		/////////////////////////////////////////////////////////////////////
		// OVERRIDES
		/////////////////////////////////////////////////////////////////////
 
		/////////////////////////////////////////////////////////////////////
		// PRIVATE METHODS
		/////////////////////////////////////////////////////////////////////
	}
}

package labs.otuome.air.myapp.model.proxy.google
{
	import com.google.analytics.AnalyticsTracker;
	import com.google.analytics.GATracker;
 
	import flash.display.DisplayObject;
 
	import labs.otuome.air.myapp.model.proxy.AbstractProxy;
	import labs.otuome.air.myapp.model.vo.google.AnalyticsData;
 
	import org.puremvc.as3.interfaces.IProxy;
 
	/**
	 * The <code>AnalyticsProxy</code> class 
	 * provides access to the AnalyticsData, which 
	 * contains all of the associated analytics data. 
	 * 
	 * @author Hasan Otuome (core)
	 */	
	public class AnalyticsProxy extends AbstractProxy implements IProxy
	{
		/////////////////////////////////////////////////////////////////////
		// PRIVATE PROPERTIES
		/////////////////////////////////////////////////////////////////////
		/**
		 * The GA tracker object. 
		 */		
		private var _googleAnalyticsTracker:AnalyticsTracker;
		/////////////////////////////////////////////////////////////////////
		// PUBLIC PROPERTIES
		/////////////////////////////////////////////////////////////////////
		/**
		 * Reference to class name for framework caching. 
		 */		
		public static const NAME:String = 'AnalyticsProxy';
		/**
		 * The web property ID associated with this application. 
		 */		
		public static const GOOGLE_ANALYTICS_PROPERTY_ID:String = 'UA-12346578-1';
		/**
		 * Returns the AnalyticsData.
		 */		
		public function get track():AnalyticsData{ return getData() as AnalyticsData; }
		/////////////////////////////////////////////////////////////////////
		// PUBLIC METHODS
		/////////////////////////////////////////////////////////////////////
		/**
		 * Constructor
		 *  
		 * @param aName
		 * @param aData
		 */		
		public function AnalyticsProxy( aName:String, aData:Object=null )
		{
			super( aName, aData );
		}
		/**
		 * Starts the GA tracker. 
		 * @param displayObject
		 * @param debug
		 */		
		public function initializeGoogleTracker( displayObject:DisplayObject, debug:Boolean=false ):void
		{
			_googleAnalyticsTracker = new GATracker( displayObject, GOOGLE_ANALYTICS_PROPERTY_ID, 'AS3', false );
		}
		/**
		 * Submits the analytics data to 
		 * the analytics tracking service.
		 */		
		public function submitUsageData():void
		{
			if (track.type && track.value)
			{
				switch (track.type)
				{
					case AnalyticsData.URL:
						_trackPageView();
						break;
					case AnalyticsData.EVENT:
						_trackEvent();
						break;
				}
			}
		}
		/////////////////////////////////////////////////////////////////////
		// OVERRIDES
		/////////////////////////////////////////////////////////////////////
		/**
		 * Proxy registration handler.
		 */
		override public function onRegister():void
		{
			debugTrace( '[ AnalyticsProxy :: onRegister() ]' );
 
			data = new AnalyticsData();
		}
		////////////////////////////////////////////////////////////////////
		// PRIVATE METHODS
		////////////////////////////////////////////////////////////////////
		/**
		 * Submits a virtual page view. 
		 */		
		private function _trackPageView():void
		{
			if (_googleAnalyticsTracker) 
			{
				_googleAnalyticsTracker.trackPageview( track.value.toString() );
 
				// reset the VO
				track.type = null;
				track.value = null;
				track.category = null;
				track.action = null;
				track.label = null;
			}	
		}
		/**
		 * Submits a virtual event. 
		 */		
		private function _trackEvent():void
		{
			if (_googleAnalyticsTracker) 
			{
				_googleAnalyticsTracker.trackEvent( track.category, track.action, track.label, Number(track.value) );
 
				// reset the VO
				track.type = null;
				track.value = null;
				track.category = null;
				track.action = null;
				track.label = null;
			}
		}
	}
}

java.args=-Xmx384m -Dsun.io.useCanonCaches=false

java.args=-Xmx512m -Dsun.io.useCanonCaches=false