Architect, Engineer, Tech Enthusiast - Hasan Otuome » AS2

AS2 :: Animator Class

Hasan Otuome — Thu, 17 Aug 2006 08:00:00 +0000

Nothing special here. This is just a helper class for the TileMaker class. It only has (1) method animate which I made static so you don’t have to create instances of this class.

import mx.transitions.Tween;
import mx.transitions.easing.*;
 
class org.thesourcecode.effects.Animator extends MovieClip
{
 
	private function Animator(){ super(); }
 
	static public function animate( clip:MovieClip, newx:Number, newy:Number, tweenType:Function )
	{
		var xTween:Tween =  new Tween( clip,"_x",tweenType,clip._x,newx,3,true );
		var yTween:Tween =  new Tween( clip,"_y",tweenType,clip._y,newy,3,true );
	}
}

This class is part of the easy-install extenstion for the TileMaker class.
No documentation necessary.

Buffer

AS2 :: XMLMenu Class

Hasan Otuome — Wed, 26 Jul 2006 08:00:00 +0000

Goal: minimize the amount of code rewrite involved in creating XML-based menus in Flash. You can customize the Class to match the structure of your XML file.

class org.thesourcecode.utils.XMLMenu extends MovieClip
{
	//declare your variables
	private var _i:Number;
	private var _j:Number;
	private var _mainTL;
	private var _btns:XML;
	private var _butz:Array;
	private var _tmpX:Number;
	private var _tmpY:Number;
	private var _btn;
	private var _xmlfile:String;
	private var _menutarget:MovieClip;
	private var _space:Number;
	private var _vertical:Boolean;
 
	public function XMLMenu()
	{
 
	}//end constructor
 
	public function buildMenu( file:String,target:MovieClip, space:Number, vertical:Boolean )
	{
		_buildIt( file, target, space, vertical );
	}//end public function
 
	private function _buildIt( filesource, destination, separation, isVertical )
	{
		_xmlfile = filesource;
		_btns = new XML();
		_btns.ignoreWhite = true;
		_btns.onLoad = function()
		{
			_menutarget = destination;
			_space = separation;
			_vertical = isVertical;
			_mainTL = _menutarget._parent;
			_butz = this.firstChild.childNodes;
			for (_i=0,_j=1; _i<_butz .length; _i++,_j++)
			{
				_space = _i*separation;
				if (_vertical)
				{
					_tmpX = 0;
					_tmpY = _space;
				} 
				else
				{
					_tmpX = _space;
					_tmpY = 0;
				}
				_btn = _menutarget.attachMovie( "btn","btn"+_j,_i+100,{_x:_tmpX,_y:_tmpY} );
				_btn.selector._visible = false;
				_btn.sec.lbl.text = _butz[_i].attributes.lbl;
				_btn.loc = _butz[_i].attributes.loc;
				_btn.hdr = _butz[_i].attributes.hdr;
				_btn.desc = _butz[_i].attributes.desc;
				_btn.onRollOver = _mainTL.rollover;
				_btn.onRollOut = _mainTL.rollout;
				_btn.onPress = _mainTL.select;
				_mainTL.btns.push( "btn"+_j );
			}
		}
		_btns.load( _xmlfile );
	}//end main menu function
}//end class

Download the easy-install extension here.
Documentation can be found here.

Buffer

AS2 :: CuePoints Class

Hasan Otuome — Sun, 16 Jul 2006 08:00:00 +0000

Goal: Wanted to simplify cue point usage for FLVs that needed text captions. The repetitive static code is placed in the class file leaving the dynamic stuff for the FLA.

import mx.utils.Delegate;
 
class org.thesourcecode.utils.CuePoints
{
	private var _vid;
	private var _arr:Array;
	private var _ct:TextField;
	private var _cf:Function;
 
	public function CuePoints( co:Object )
	{
		_vid = co.video;
		_arr = co.cues;
		_ct = co.textbox;
		_cf = co.animation;
 
		_vid.addEventListener( "cuePoint", Delegate.create(this,_onCue) );
	}//end constructor
 
	private function _onCue( cue:Object ):Void
	{
		for (var i=0; i<_arr .length; i++)
		{
			if (cue.info.name == _arr[i].cueName)
			{
				_ct.text = _arr[ i ].cueText;
				_cf();
			}
		}
	}//end function
}//end class

Download the easy-install extension from here.
Documentation can be found here.

Buffer

AS2 :: TileMaker Class

Hasan Otuome — Sun, 09 Jul 2006 08:00:00 +0000

Came up with this one after a number of posts over @ gotoAndLearn() about making grids from XML files. Since I’m all about reusability, I devised an easy way to create animated thumnail tiles for an XML photo gallery could be an XML video gallery too. Just feed in the required parameters and off you go. Button events could easily be added to the thumbnails also.

import mx.utils.Delegate;
import org.thesourcecode.effects.Animator;
 
class org.thesourcecode.utils.TileMaker
{
	private var _xmlfile:String;
	private var _gridType:String;
	private var _increment:Number;
	private var _i:Number;
	private var _j:Number;
	private var _k:Number;
	private var _numOf:Number;
	private var _colSpacing:Number;
	private var _rowSpacing:Number;
	private var _xOffset:Number;
	private var _yOffset:Number;
	private var _xml:XML;
	private var _ROOT:MovieClip;
	private var _targetClip:MovieClip
	private var _mcl:MovieClipLoader;
	private var _listener:Object;
	private var _obj:Object;
	private var _tween:Boolean;
	private var _tweenType:Function;
 
	public function TileMaker( parent:MovieClip,tween:Boolean )
	{
		_ROOT = parent;
		_obj = new Object;
		_mcl = new MovieClipLoader;
		if (tween)
		{
			var _tweenType = mx.transitions.easing.Elastic.easeInOut;
		} 
		else 
		{
			var _tweenType = mx.transitions.easing.None.easeNone;
		}
	}//end constructor
 
	public function makeTiles( xmlfile:String, 
		targetClip:MovieClip, 
		gridType:String, 
		numOf:Number, 
		rowSpacing:Number, 
		colSpacing:Number, 
		xOffset:Number, 
		yOffset:Number ):Void
	{
		_xmlfile = xmlfile;
		_targetClip = targetClip;
		_gridType = gridType;
		_numOf = numOf;
		_rowSpacing = rowSpacing;
		_colSpacing = colSpacing;
		_xOffset = xOffset;
		_yOffset = yOffset;
		_xml = new XML();
		_xml.ignoreWhite = true;
		_xml.onLoad = Delegate.create( this,_makeGrid );
		_xml.load( _xmlfile );
	}
 
	private function _makeGrid()
	{
		var nodes:Array = _xml.firstChild.childNodes;
		_listener = new Object();
		_mcl.addListener( _listener );
		for (_i=0, _j=1, _k=-1; _k < nodes .length; _i++, _j++, _k++)
		{
			var contents:String = nodes[ _k ].attributes.thumb;
			var row = (_i-1) % _numOf;
			var col = Math.floor( (_i-1) / _numOf );
			var tmp:MovieClip = _targetClip.createEmptyMovieClip( "box"+_j,_targetClip.getNextHighestDepth() );
			tmp._x = -100;
			tmp._y = -100;
			_mcl.loadClip( contents,tmp );
			_listener.onLoadInit = function( tmp )
			{
				if (tmp._width > 100 && tmp._height > 100)
				{
					tmp._xscale = 50;
					tmp._yscale = 50;
				}
			}
			if (_gridType == "row")
			{
				_obj.X = ( row*_rowSpacing ) + _yOffset;
				_obj.Y = ( col*_colSpacing ) + _xOffset;
			} 
			else 
			{
				_obj.Y = ( row*_rowSpacing ) + _yOffset;
				_obj.X = ( col*_colSpacing ) + _xOffset;
			}
			Animator.animate( tmp, _obj.X, _obj.Y, _tweenType );
		}
	}
}//end class

You can download an easy-install extension plus sample files here.
Documentation can be found here.

Buffer

AS2 :: FlashCookie Class

Hasan Otuome — Sat, 08 Jul 2006 08:00:00 +0000

Goal: Create a simple way to incorporate SharedObjects into Flash-based forms.

class org.thesourcecode.utils.FlashCookie
{
   private var _mainTL:MovieClip;
   private var _cookie:SharedObject;
   private var _cookieName:String;
   private var _chips:Object;
 
   public function FlashCookie( newCookie:String,target:MovieClip )
   {
      this._cookieName = newCookie;
      _cookie = SharedObject.getLocal( _cookieName );
      _mainTL = target;
   }
 
   public function bakeCookie( obj:Object ):Void
   {
      var i:String;
      for (i in obj)
      {
         _cookie.data[ i ] = obj[ i ];
         _cookie.flush();
      }
   }
 
   public function getChip( str:String ):String
   {
      return _cookie.data[ str ];
   }
 
   public function getChips():Object
   {
      _chips = _cookie.data;
      return _chips;
   }
 
   public function getCookieName():String
   {
      return _cookieName;
   }
 
   public function checkCookie( prop:String, fields:Array )
   {
	   if (_cookie.data[prop] != undefined)
	   {
		   var i:Number;
		   for (i=0; i < fields.length; i++)
		   {
			   _mainTL[ fields[i] ].text = _cookie.data[ fields[i] ];
		   }
	   }
   }
 
   public function addChips( fields:Array )
   {
	   var i:Number;
	   for (i=0; i<fields.length; i++)
	   {
		   //trace( _mainTL[fields[i]].text );
		   _cookie.data[  fields[i] ] = _mainTL[ fields[i] ].text;
	   }
	   _cookie.flush();
   }
 
   public function eatCookie()
   {
	   _cookie.clear();
   }
 
}

Download the easy-install extension and sample files here.

Documentation can be found here.

Buffer

AS2 :: Guestbook Class

Hasan Otuome — Fri, 07 Jul 2006 08:00:00 +0000

Goal: To devise an easy way to add user interaction to a full-Flash site, in this case a guestbook.

class org.thesourcecode.utils.Guestbook
{
	private var _earl:String;
	private var _display;
	private var _getEntries:LoadVars;
	private var _sender:LoadVars;
	private var _receiver:LoadVars;
	private var _refresh:LoadVars;
	private var _mainTL:MovieClip;
	private var _validname:Boolean;
	private var _validemail:Boolean;
	private var _validcity:Boolean;
	private var _validmsg:Boolean;
	private var _array:Array;
	private var _uri:String;
 
	public function Guestbook( target:MovieClip )
	{
		_mainTL = target;
	}//end constructor
 
	//retreive the specified posts
	public function getPosts( url:String, target, min:Number, max:Number )
	{
		_earl = url;
		_display = target;
		_getEntries = new LoadVars();
		_getEntries.onLoad = function( success:Boolean )
		{
			if (success)
		{
				target.text = this.strflash;
			} 
		else 
		{
				target.text = this.strflash;
			}
		}
		_getEntries.load(_earl);
	}
 
	//get the user-entered info and insert into the database
	public function addPost( fields:Array, url:String,target )
	{
		_array = fields;
		_uri = url;
		_display = target;
		checkPost();
	}
 
	//basic validation stuff
	private function checkPost()
	{
		_validname = false;
		_validemail = false;
		_validcity = false;
		_validmsg = false;
		if (_mainTL.gname.text != "")
		{
			_validname = true;
		} 
		else 
		{
			_mainTL.msg.text = "Please complete all fields"
		}
		if (_mainTL.gmail.text == "") 
		{
			_mainTL.msg.text = "I need your email address";
		} 
		else if (_mainTL.gmail.text.indexOf("@") == -1 
		   || _mainTL.gmail.text.indexOf(".") == -1) 
		{
			_mainTL.msg.text = "Please provide a valid email";
		} 
		else
		 {
			_validemail = true;
		}
		if (_mainTL.gfrom.text != "")
		{
			_validcity = true;
		} 
		else 
		{
			_mainTL.msg.text = "Please complete all fields"
		}
		if (_mainTL.gmsg.text != "")
		{
			_validmsg = true;
		} 
		else 
		{
			_mainTL.msg.text = "Please complete all fields"
		}
		processCheck();
	}
 
	//2nd phase of validation (puts 2 steps between the FLA and class
	private function processCheck()
	{
		if (_validname && _validemail && _validcity && _validmsg)
		{
			_addPost( _array,_uri,_display );
		}
	}
 
	//now you can send the data
	private function _addPost( flds:Array,script:String,target )
	{
		_sender = new LoadVars();
		_receiver = new LoadVars();
 
		_receiver.onLoad = function()
		{
			_mainTL.msg.text = this.statusMsg;
		}/**/
 
		for (var i=0; i < flds .length; i++)
		{
			_sender[ flds[i] ] = _mainTL[ flds[i] ].text;
			trace( _sender[flds[i]] ); //use for debugging
			_mainTL[ flds[i] ].text = "";
		}
		_sender.sendAndLoad( script,_receiver,"POST" );
 
		getPosts( _earl,target );
	}
 
}//end class

Download the easy-install extension and sample files here
Documentation can be found here.

Buffer

AS2 :: BackgroundFill Class

Hasan Otuome — Thu, 06 Jul 2006 08:00:00 +0000

Goal: To devise an easy reusable way to create seamless backgrounds for full-screen Flash movies whether it be gradients or bitmaps. Works with a “bg” Object customized to your needs.

import flash.display.BitmapData;
import flash.geom.Matrix;
 
class org.thesourcecode.utils.BackgroundFill
{
	private var _main:MovieClip;
	private var _sub:MovieClip;
	private var _w:Number;
	private var _h:Number;
	private var _gradient:Object;
	private var _bitmap:String;
	private var _fillType:String;
	private var _colors:Array;
	private var _alphas:Array;
	private var _ratios:Array;
	private var _matrix:Matrix;
	private var _tile:BitmapData;
 
	public function BackgroundFill( clip:MovieClip )
	{
		_main = clip;
	}//end constructor
 
	public function fillBg( bg:Object ):Void
	{
		_w = Stage.width;
		_h = Stage.height;
		_bitmap = bg.bitmap;
		_gradient = bg.gradient;
		_main.clear();
		_main.lineStyle( 1, 0xFFFFFF, 0 );
		_sub.clear();
		_sub.lineStyle( 1, 0xFFFFFF, 0 );
		if (!_gradient)
		{
			_tile = BitmapData.loadBitmap( _bitmap );
			_main.beginBitmapFill( _tile );
			_main.moveTo( 0, 0 );
		} 
		else if (!_bitmap)
		{
			if (_gradient.radial)
			{
				_fillType = "radial";
				_matrix = new Matrix();
				_matrix.createGradientBox( _w, _h, 0, 0, 0 );
			} 
			else 
			{
				_fillType = "linear";
				_matrix = new Matrix();
				_matrix.createGradientBox( _w, _h, 90/180 * Math.PI, 0, 0 );
			}
			//use the defaults for spreadMethod("pad"), interpolationMethod("RGB") and focalPointRatio(0)
			_colors = [ _gradient.c1, _gradient.c2 ];
			_alphas = [ _gradient.a1, _gradient.a2 ];
			_ratios = [ _gradient.r1, _gradient.r2 ];
			_main.beginGradientFill( _fillType, _colors, _alphas, _ratios, _matrix );
		} 
		else 
		{
			_tile = BitmapData.loadBitmap( _bitmap );
			_main.beginBitmapFill( _tile );
			_main.moveTo( 0, 0 );
			if (_gradient.radial)
			{
				_fillType = "radial";
				_matrix = new Matrix();
				_matrix.createGradientBox( _w, _h, 0, 0, 0 );
			} 
			else 
			{
				_fillType = "linear";
				_matrix = new Matrix();
				_matrix.createGradientBox( _w, _h, 90/180 * Math.PI, 0, 0 );
			}
			_colors = [ _gradient.c1, _gradient.c2 ];
			_alphas = [ _gradient.a1, _gradient.a2 ];
			_ratios = [ _gradient.r1, _gradient.r2 ];
			_sub = _main.createEmptyMovieClip( "sub",_main.getNextHighestDepth() );
			_sub.beginGradientFill( _fillType, _colors, _alphas, _ratios, _matrix );
			_sub.lineTo( _w, 0 );
			_sub.lineTo( _w, _h );
			_sub.lineTo( 0, _h );
			_sub.lineTo( 0, 0 );
			_sub.endFill();
		}
		_main.lineTo( _w, 0 );
		_main.lineTo( _w, _h );
		_main.lineTo( 0, _h );
		_main.lineTo( 0, 0 );
		_main.endFill();
	}
}//end class

Download the easy-install extension and sample files here.
Documentation can be found here.

Buffer